كيفية استخدام وظائف TOCOL و TOROW في Microsoft Excel

إن إعادة تشكيل مجموعة ثنائية الأبعاد من البيانات في عمود واحد أو صف واحد في Microsoft Excel يقلل من تخطيط أرقامك ويجعل التصفية والتصفية أكثر كفاءة. لهذه الأسباب ، يجب أن تعرف كيف تعمل وظائف Tocol و Torow الخاصة بـ Excel.

وظيفة TOCOL: تحويل صفيف ثنائي الأبعاد إلى عمود واحد

كما يوحي اسمها ، تحول وظيفة TOCOL من Excel مجموعة من الأعمدة والصفوف المتعددة إلى عمود واحد من البيانات أحادية البعد.

بناء الجملة لهذه الوظيفة هو كما يلي:

=TOCOL(a,(b),(c))

أين

• أ (مطلوب) هو الصفيف للعودة كعمود ،
• ب (اختياري) يحدد ما إذا كانت النتيجة يجب أن تتجاهل أنواعًا معينة من القيم ، و
• ج (اختياري) يحدد ما إذا كان ينبغي مسح الصفيف ضوئيًا حسب العمود أو الصف.

إذا حذفت الحجة ب، تعود الصيغة الجميع قيم صفيف المصدر في العمود الناتج. لكن، 1 يخبر Excel بتجاهل الفراغات ، 2 يخبر Excel بتجاهل الأخطاء ، و 3 يخبر Excel بتجاهل الفراغات والأخطاء.

حذف الحجة ج يقوم بمسح الصفيف بالصف من اليسار إلى اليمين ، بدءًا من الصف العلوي. من ناحية أخرى ، القيمة المنطقية حقيقي يطلب من Excel مسح الصفيف بالعمود من أعلى إلى أسفل ، بدءًا من العمود في أقصى اليسار.

تخيل أنك الرئيس التنفيذي لشركة البيع بالتجزئة ، ولديك جدول بيانات يحتوي على أنواع المتاجر في العمود A ، والبلدان في الصف 1 ، واسم المدير في كل خلية متقاطعة.

هدفك هو تحويل مجموعة أسماء المدير في الخلية B2 إلى الخلية F17 إلى عمود واحد ، والتي ستستخدمها كنقطة انطلاق لمجموعة بيانات جديدة.

دعونا أولاً نلقي نظرة على Tocol في أبسط أشكاله ، باستخدام الوسيطة المطلوبة فقط. في خلية فارغة ، اكتب:

=TOCOL(

ثم حدد الخلايا التي تحتوي على القيم التي تريد إدراجها في عمود واحد.

بعد ذلك ، أغلق الأقواس في نهاية الصيغة ، واضغط على Enter.

=TOCOL(B2:F17)

يظهر عمود الأسماء 1D الناتج كصفيف ديناميكي ينشر من الخلية حيث كتبت الصيغة.

نظرًا للنتيجة الديناميكية ، فسيقوم بتبني أي تغييرات على البيانات الأصلية. ومع ذلك ، ضع في اعتبارك أن المصفوفات الديناميكية غير متوافقة مع جداول Excel. هذا يعني أنه إذا كنت ترغب في تنسيق قائمة 1D كجدول Excel ، أولاً ، ستحتاج إلى تحديد جميع الخلايا في النتيجة ، واضغط على Ctrl+C لنسخها ، واضغط على Ctrl+Shift+V للصقها كقيم. ومع ذلك ، في هذه المرحلة ، لم تعد القائمة الناتجة مرتبطة بالبيانات الأصلية ، لذلك لن تعكس أي تغييرات لاحقة تم إجراؤها.

لأنك حذفت الحجة ب (القيم التي يجب تجاهلها) ، تُرجع النتيجة جميع القيم ، بما في ذلك الفراغات (كما هو موضح كأصفار) والأخطاء. أيضا ، لأنك حذفت الحجة ج (اتجاه المسح الضوئي) ، يسرد النتيجة القيم التي ظهرت في المصدر من اليسار إلى اليمين على الصف الأول (جميع مديري السوبر ماركت) ، ثم الصف الثاني (جميع مديري الصحف) ، وما إلى ذلك.

أثناء ترك الأصفار والأخطاء في النتيجة قد يكون مفيدًا في بعض السياقات – مثل ما إذا كنت ترغب في تحليل انتشارها في بيانات المصدر – في معظم الوقت ، ستكون البيانات أكثر نظافة إذا كنت تجبر التفوق على إخفاءها. للقيام بذلك ، استخدم نفس الصيغة ، ولكن اكتب 3 للحجة ب:

=TOCOL(B2:F17,3)

واضغط على إدخال.

أخيرًا ، بدلاً من مسح الصفيف الأصلي حسب الصف ، لنفترض أنك تريد مسحها حسب العمود. وهذا يعني أنك تريد أن تكون النتيجة لدرج القيم كما ظهرت في المصدر من أعلى إلى أسفل في العمود الأول (جميع المديرين المقيمين في الولايات المتحدة) ، ثم العمود الثاني (جميع المديرين المقيمين في المملكة المتحدة) ، وما إلى ذلك.

للقيام بذلك ، تحتاج إلى الكتابة حقيقي للحجة ج:

=TOCOL(B2:F17,3,TRUE)

وظيفة torow: تحويل صفيف ثنائي الأبعاد إلى صف واحد

تقوم وظيفة Microsoft Excel’s Torow بتحويل مجموعة من الأعمدة والصفوف المتعددة إلى صف واحد من البيانات أحادية البعد.

يعمل بناء الجملة بنفس طريقة وظيفة TOCOL:

=TOROW(a,(b),(c))

أين

• أ (مطلوب) هو الصفيف للعودة كصف ،
• ب (اختياري) يحدد ما إذا كانت النتيجة يجب أن تتجاهل أنواعًا معينة من القيم ، و
• ج (اختياري) يحدد ما إذا كان ينبغي مسح الصفيف ضوئيًا حسب العمود أو الصف.

حذف الحجة ب عودة الجميع قيم صفيف المصدر ، بما في ذلك الفراغات والأخطاء ، في الصف الناتج. لكن، 1 يخبر Excel بتجاهل الفراغات ، 2 يخبر Excel بتجاهل الأخطاء ، و 3 يخبر Excel بتجاهل الفراغات والأخطاء.

إذا حذفت الوسيطة الاختيارية ج، تقوم الوظيفة بمسح الصفيف حسب الصف من اليسار إلى اليمين ، بدءًا من الصف الأول. إذا كنت تريد ، بدلاً من ذلك ، أن تقوم بمسح الصفيف حسب العمود من أعلى إلى أسفل ، بدءًا من العمود الأول ، فأنت بحاجة إلى إضافة قيمة منطقية حقيقي.

باستخدام نفس مجموعة البيانات كما في المثال السابق ، هذه المرة ، تريد سرد جميع أسماء المديرين في صف واحد كرؤوس الأعمدة ، تحتها تكتب أسماء موظفيهم. للقيام بذلك ، في خلية فارغة ، اكتب:

=TOROW(

وحدد الخلايا في الصفيف.

ثم أغلق الأقواس واضغط على إدخال:

=TOROW(B2:F17)

تعرض النتيجة جميع الأسماء في صف واحد ، حيث تظهر الفراغات كأصفار وأخطاء.

لإجبار الوظيفة على تجاهل الفراغات والأخطاء ، اكتب 3 للحجة ب. أيضًا ، لمسح البيانات الأصلية حسب العمود بدلاً من الصف ، اكتب حقيقي للحجة ج:

=TOROW(B2:F17,3,TRUE)

لتحويل النتيجة من القيم الديناميكية إلى الثابتة ، حدد جميع الخلايا ، واضغط على CTRL+C لنسخها ، واضغط على CTRL+Shift+V للصقها كقيم.

دمج صفائف متعددة في عمود واحد أو صف

تستخدم في عزلة ، يمكن لـ Tocol و Torow تحويل مجموعة واحدة فقط إلى عمود أو صف من البيانات. ومع ذلك ، عند استخدامها جنبًا إلى جنب مع VStack و HSTACK ، يمكنهم دمج صفائف متعددة في عمود أو صف من البيانات.

هنا ، لديك مجموعتان من البيانات – الأول يحتوي على مدير كل متجر من قبل البلد الأوروبي ، والثاني يحتوي على نفس التفاصيل لآسيا. هدفك هو إعادة إنتاج جميع أسماء المديرين من كلا المصفمين في عمود واحد.

فستاك يتراكم صفائف متعددة فوق بعضها البعض. يمكنك رؤية هذا في العمل في لقطة الشاشة أدناه.

=VSTACK(B2:F17,B20:F35)

نتيجة لذلك ، إذا كنت تعشش Vstack داخل صيغة Tocol ، فسيتم إدراج أسماء جميع المديرين الأوروبيين في ROW First ، تليها جميع المديرين الآسيويين عن طريق الصف.

=TOCOL(VSTACK(B2:F17,B20:F35),3)

من ناحية أخرى ، تتراكم HSTACK صفائف متعددة بجوار بعضها البعض.

=HSTACK(B2:F17,B20:F35)

لذلك ، إذا كنت تعشق Hstack داخل Tocol ، فإن العمود الناتج يسرد أولاً جميع مديري السوبر ماركت (أوروبا ، آسيا) ، ثم جميع مديري الصحف (أوروبا ، آسيا) ، وما إلى ذلك.

=TOCOL(HSTACK(B2:F17,B20:F35),3)

تذكر أنه يمكنك أيضًا تضمين الوسيطة الثالثة لوظائف Tocol و Torow لزيادة تعريف ترتيب النتيجة.

تحويل صفيف ثنائي الأبعاد إلى عمود واحد من القيم الفريدة والفرز

يمكن تداخل وظائف Excel’s Tocol و Torow داخل مجموعة كاملة من وظائف تنظيم البيانات المفيدة. اثنان من أكثر الصحابة المفيدة من Tocol و Torow هي منفردة وفريدة من نوعها.

دعنا نقول أنك مدير ألعاب القوى ، ولديك مجموعة من الفائزين بالميدالية الذهبية في مختلف الأحداث على مدار السنوات الخمس الماضية.

هدفك هو تحويل جميع الأسماء إلى عمود واحد. باستخدام TOCOL فقط ، ستكتب:

=TOCOL(B2:F17)

ومع ذلك ، يظهر بعض الأشخاص أكثر من مرة في القائمة لأنهم فازوا بميداليات ذهبية متعددة. لذلك ، لتجنب التكرار ، تحتاج إلى عش صيغة Tocol بالكامل داخل الفريدة:

=UNIQUE(TOCOL(B2:F17))

أخيرًا ، تريد فرز هذه القيم الفريدة إلى ترتيب أبجدي ، وهو الترتيب الافتراضي المعتمد بواسطة وظيفة الفرز. لذلك ، يمكنك لف الصيغة الفريدة من نوعها في النوع:

=SORT(UNIQUE(TOCOL(B2:F17)))

لفرز النتيجة في ترتيب عكسي ، اكتب -1 ل ثالث حجة جزء من النوع من الصيغة:

=SORT(UNIQUE(TOCOL(B2:F17)),,-1)

تعمل الوسيطات الافتراضية للوظائف الفريدة والفريدة بشكل أفضل مع المصفوفات المستندة إلى الأعمدة (بدلاً من المصفوفات المستندة إلى الصف). لاستخدام هاتين الوظيفتين إلى جانب Torow ، يجب عليك الكتابة حقيقي ل ثانية حجة الجزء الفريد من الصيغة ، و حقيقي ل رابع حجة جزء من النوع من الصيغة:

=SORT(UNIQUE(TOROW(B2:F17),TRUE),,,TRUE)

وظائف TOCOL و TOROW ليست سوى طريقتين لإعادة ترتيب البيانات في Microsoft Excel. على سبيل المثال ، يمكنك قلب الصفوف والأعمدة باستخدام وظيفة transpose ، أو تحويل مجموعات البيانات الكبيرة باستخدام المواد القابلة للاستبدال ، أو الجمع بين أوراق العمل باستخدام استعلام الطاقة.

نظام التشغيل

Windows و MacOs و iPhone و iPad و Android

تجربة مجانية

1 شهر

يتضمن Microsoft 365 الوصول إلى تطبيقات Office مثل Word و Excel و PowerPoint على ما يصل إلى خمسة أجهزة ، و 1 تيرابايت من التخزين OneDrive ، وأكثر من ذلك.